Add ios-webkit-debug-proxy

common/packages.nix

@@ -28,6 +28,7 @@ overrideUntilVersion {
   darktable = "4.0.0";
   efficient-compression-tool = "0.9.1";
   gpx-reduce = "unstable-2021-05-04";
+  ios-webkit-debug-proxy = "unstable-2021-08-12";
   tile-stitch = "unstable-2019-07-10";
   zsh-abbr = "4.5.0";
 } // fromLocal {

hosts/main/nixos.nix

@@ -75,9 +75,12 @@
     "10-wifi".linkConfig.Name = "wifi";
   };
 
+  # usbmuxd
+  services.usbmuxd.enable = true;
+
   # Wireshark
   programs.wireshark.enable = true;
-  users.users.ak.extraGroups = [ "wireshark" ];
+  users.users.ak.extraGroups = [ "usbmux" "wireshark" ];
 
   # UniFi Network application
   services.unifi = { enable = true; openFirewall = false; };

packages/ios-webkit-debug-proxy.nix

@@ -0,0 +1,66 @@
+{ lib
+, fetchFromGitHub
+, stdenv
+
+  # Dependencies
+, autoreconfHook
+, libimobiledevice
+, libplist
+, openssl
+, pkg-config
+}:
+
+let
+  libimobiledeviceWithOpenssl = libimobiledevice.overrideAttrs (l: {
+    nativeBuildInputs = l.nativeBuildInputs ++ [ openssl ];
+    configureFlags = lib.remove "--disable-openssl" l.configureFlags;
+  });
+in
+stdenv.mkDerivation {
+  pname = "ios-webkit-debug-proxy";
+  version = "unstable-2021-08-12";
+
+  src = fetchFromGitHub {
+    owner = "google";
+    repo = "ios-webkit-debug-proxy";
+    rev = "d33433dfce4edb024ce34573fa64f80c80a1676e";
+    hash = "sha256-YzjMKf+mudGbiBwDDxy5YE5CkQcePjgo7eouMIgw7J4=";
+  };
+
+  patches = [ (builtins.toFile "fixup-697dbc5.patch" ''
+    --- a/src/device_listener.c
+    +++ b/src/device_listener.c
+    @@ -32 +32 @@
+    -#include "device_listener.h"
+    +#include "ios-webkit-debug-proxy/device_listener.h"
+    --- a/src/socket_manager.c
+    +++ b/src/socket_manager.c
+    @@ -34 +34 @@
+    -#include "socket_manager.h"
+    +#include "ios-webkit-debug-proxy/socket_manager.h"
+    --- a/src/webinspector.c
+    +++ b/src/webinspector.c
+    @@ -33 +33 @@
+    -#include "webinspector.h"
+    +#include "ios-webkit-debug-proxy/webinspector.h"
+    --- a/src/websocket.c
+    +++ b/src/websocket.c
+    @@ -15 +15 @@
+    -#include "websocket.h"
+    +#include "ios-webkit-debug-proxy/websocket.h"
+  '') ];
+
+  nativeBuildInputs = [
+    autoreconfHook
+    libimobiledeviceWithOpenssl
+    libplist
+    openssl
+    pkg-config
+  ];
+
+  meta = {
+    description = "A DevTools proxy (Chrome Remote Debugging Protocol) for iOS devices (Safari Remote Web Inspector)";
+    homepage = "https://github.com/google/ios-webkit-debug-proxy";
+    license = lib.licenses.bsd3;
+  };
+}