_: pkgs:

let unstable = import <unstable> { inherit (pkgs) config; overlays = [ ]; }; in
with import ../packages/override-utils.nix { inherit pkgs unstable; };

unstableUntil {
  ansible-vault-pass-client = any;
  apex = any;
  cavif = any;
  decompiler-mc = any;
  fastnbt-tools = any;
  git-diff-image = any;
  gpx-reduce = any;
  ios-safari-remote-debug-kit = any;
  ios-webkit-debug-proxy = any;
  mcaselector = any;
  minemap = any;
  nbt-explorer = any;
  nix-update-script = release "23.05"; # NixOS/nixpkgs#203371, NixOS/nixpkgs#207703
  obsidian = "1.1.9"; # NixOS/nixpkgs#213593
  pngquant-interactive = any;
  tile-stitch = any;
  trafilatura = any;
  wireguard-vanity-address = any;
} // local {
  add-words = { };
  affine = { };
  attachments = { };
  email-hash = { };
  git-diff-minecraft = {};
  github-remote = { };
  gopass-await = { inherit (pkgs.gnome) zenity; };
  gopass-ydotool = { };
  iosevka-custom = { };
  mozjpeg-simple = { };
  off = { };
  zsh-abbr = { };
  zsh-click = { };
} // {
  # Workaround for https://bugzilla.mozilla.org/show_bug.cgi?id=1269895
  firefox = pkgs.firefox.overrideAttrs (wrapper: {
    buildCommand = wrapper.buildCommand + ''
      wrapProgram "$executablePath" --unset 'LC_TIME'
    '';
  });

  # Pending https://gitlab.gnome.org/GNOME/gnome-shell/-/issues/5370
  gnome = pkgs.gnome.overrideScope' (_: gnome: {
    gnome-shell = gnome.gnome-shell.overrideAttrs (gnome-shell: {
      patches = gnome-shell.patches or [ ] ++ [ ../packages/resources/gnome-shell_screenshot-location.patch ];
    });
  });

  # Required by https://gubaer.github.io/josm-scripting-plugin/docs/graaljs
  josm = pkgs.josm.override { jre = pkgs.graalvm17-ce; };

  # Enable tray icon
  signal-desktop = pkgs.signal-desktop.overrideAttrs (signal-desktop: {
    preFixup = signal-desktop.preFixup + ''
      gappsWrapperArgs+=(--add-flags --use-tray-icon)
    '';
  });

  # Workaround for mangled keybindings
  vscodium = pkgs.vscodium.overrideAttrs (vscodium: {
    preFixup = vscodium.preFixup + ''
      gappsWrapperArgs+=( --unset NIXOS_OZONE_WL )
    '';
  });

  # Workaround for https://gitlab.com/kevincox/watchlog/-/issues/6
  watchlog = unstable.watchlog.overrideAttrs (watchlog: until watchlog "1.201.0" {
    nativeBuildInputs = watchlog.nativeBuildInputs ++ [ pkgs.makeWrapper ];
    postInstall = "wrapProgram $out/bin/wl --set CARGO_PKG_NAME 'watchlog'";
  });

  # Set GNOME Shell font
  yaru-theme = pkgs.yaru-theme.overrideAttrs (yaru-theme: {
    patches = yaru-theme.patches or [ ] ++ [ ../packages/resources/yaru-theme_font.patch ];
  });

  # Pending https://github.com/ReimuNotMoe/ydotool/issues/177
  ydotool = pkgs.ydotool.overrideAttrs (ydotool: {
    patches = ydotool.patches or [ ] ++ [ ../packages/resources/ydotool-halmakish.patch ];
  });
}