65 lines
2.1 KiB
Nix
65 lines
2.1 KiB
Nix
_: pkgs:
|
|
|
|
with pkgs.lib;
|
|
|
|
let
|
|
local = p: deps: pkgs.callPackage ../packages/${p}.nix deps;
|
|
fromLocal = pd: builtins.mapAttrs local pd;
|
|
|
|
unstable = import <unstable> { inherit (pkgs) config; overlays = [ ]; };
|
|
overrideUntilVersion = pv: builtins.mapAttrs
|
|
(p: v:
|
|
let
|
|
inStable = pkgs ? ${p} && versionAtLeast pkgs.${p}.version v;
|
|
inUnstable = unstable ? ${p} && versionAtLeast unstable.${p}.version v;
|
|
inLocal = pathExists ../packages/${p}.nix;
|
|
in
|
|
assert assertMsg (! inStable) "${p} ${v} no longer requires an override"; if inUnstable
|
|
then assert assertMsg (! inLocal) "${p} ${v} no longer requires local packaging"; unstable.${p}
|
|
else local p { }
|
|
)
|
|
pv;
|
|
in
|
|
overrideUntilVersion {
|
|
apex = "unstable-2021-12-08";
|
|
cavif = "1.3.5";
|
|
git-diff-image = "unstable-2022-11-17";
|
|
gpx-reduce = "unstable-2021-05-04";
|
|
ios-safari-remote-debug-kit = "unstable-2022-06-21";
|
|
ios-webkit-debug-proxy = "unstable-2021-08-12";
|
|
tile-stitch = "unstable-2019-07-10";
|
|
zsh-abbr = "4.5.0";
|
|
} // fromLocal {
|
|
add-words = { };
|
|
gh = { };
|
|
gopass-await = { inherit (pkgs.gnome) zenity; };
|
|
gopass-ydotool = { };
|
|
iosevka-custom = { };
|
|
mozjpeg-simple = { };
|
|
off = { };
|
|
zsh-click = { };
|
|
} // {
|
|
# Workaround for https://bugzilla.mozilla.org/show_bug.cgi?id=1269895
|
|
firefox = pkgs.firefox.overrideAttrs (wrapper: {
|
|
buildCommand = wrapper.buildCommand + ''
|
|
wrapProgram "$executablePath" --unset 'LC_TIME'
|
|
'';
|
|
});
|
|
|
|
# Pending https://gitlab.gnome.org/GNOME/gnome-shell/-/issues/5370
|
|
gnome = pkgs.gnome.overrideScope' (_: gnome: {
|
|
gnome-shell = gnome.gnome-shell.overrideAttrs (gnome-shell: {
|
|
patches = gnome-shell.patches or [ ] ++ [ ../packages/resources/gnome-shell_screenshot-location.patch ];
|
|
});
|
|
});
|
|
|
|
vscodium = pkgs.vscodium.overrideAttrs (vscodium: {
|
|
preFixup = vscodium.preFixup + ''
|
|
gappsWrapperArgs+=( --unset NIXOS_OZONE_WL )
|
|
'';
|
|
});
|
|
|
|
ydotool = pkgs.ydotool.overrideAttrs (ydotool: {
|
|
patches = ydotool.patches or [ ] ++ [ ../packages/resources/ydotool-halmakish.patch ];
|
|
});
|
|
}
|